"Gnu in the Zoo" by "Alex Ball"
[
Copyright © 2010 Alex Ball <a.j.ball@bath.ac.uk>.

Licensed under the MIT Expat license: https://opensource.org/licenses/MIT

Reading this source code before playing the game itself will ruin it for you. You have been warned.
]

Chapter 1 - Global Settings

The story headline is "A Freedom-Focused Fantasy".
The story genre is "Fantasy".
The release number is 3.
The story creation year is 2010.

Release along with an interpreter, the source text, the library card, cover art and a solution.

Section 1 - The player

The description of the player is "You are a gnu. A gnoble gnu. The gnicest work of gnature in the zoo."

The carrying capacity of the player is one.

[5 gnus to recruit, 6 things to unlock, 1 bonus]
Use scoring. The maximum score is 12.

After unlocking something with something:
	increase the score by 1;
	continue the action;

After locking something with something:
	decrease the score by 1;
	continue the action;

Instead of exiting when the player is not in a container, try going outside.

Instead of entering when the location does not contain a container, try going inside.

Section 2 - Interacting with others

Report an actor touching (this is the replacement report touching other people rule):
	if the noun is a person:
		if the actor is the player:
			say "That would not be appropriate in this case." (A);
		otherwise if the noun is the player:
			say "[The actor] [touch] [us]." (B);
		otherwise:
			say "[The actor] [touch] [the noun]." (C);
		stop the action;
	continue the action.

The replacement report touching other people rule is listed instead of the report touching other people rule in the report touching rulebook.

A person is either asleep or awake. A person is usually awake. 

Instead of asking someone to try doing something when the noun is asleep, say "[The noun] is asleep, not under hypnosis."

For printing a locale paragraph about a thing (called the item) (this is the directly describe what's on scenery supporters in room descriptions rule):
	if the item is [not undescribed and the item is] scenery and the item does not enclose the player:
		if a locale-supportable thing is on the item:
			repeat with possibility running through things on the item:
				say "[the initial appearance of the possibility] ";
			say "[paragraph break]";
	continue the activity.

The directly describe what's on scenery supporters in room descriptions rule is listed instead of the describe what's on scenery supporters in room descriptions rule in the for printing a locale paragraph about rulebook.

Understand "hello" as a mistake ("[if the location contains at least one animal]You get the pleasantries out of the way, though you would be forgiven for skipping them. After all, this is an unsociable hour: best keep it simple. To ask someone to do something, the etiquette is [command prompt]NAME, INSTRUCTION[otherwise]You experience a pang of loneliness, and consider soliciting company by shouting into the void. No. Attracting the attention of everyone nearby is not normally part of a stealth operation[end if].").

Section 3 - Enclosures

[This is adapted from the Recipe Book example 366: Rock Garden. The idea is to allow the player to look through the bars of an enclosure.]

Intervisibility relates rooms to each other in groups. The verb to be connected with means the intervisibility relation.

Definition: a room is intervisible if it is connected with more than one room.

After deciding the scope of the player when the location is an intervisible room: 
	repeat with other place running through rooms which are connected with the location: 
		unless the other place is the location, place the other place in scope.

Rule for reaching inside a room (called target) which is connected with the location: 
	let way be the best route from the location to the target, using doors;
	if the way is not a direction:
		say "Your access to [the target] is barred.";
		deny access; 
	say "(first heading [way])[command clarification break]"; 
	try going way; 
	if the player is in the target, allow access; 
	otherwise deny access.

After looking when the location is an intervisible room:
	repeat with other place running through rooms which are connected with the location:
		if the other place is not the location, describe locale for other place.

Section 4 - The sky

[Basically, an uncovered room is outside (i.e. has sky) whereas a covered one isn't.]
A room can be covered or uncovered.

The sky is backdrop.

Looking up is an action applying to nothing. Understand "look up" as looking up.
Instead of looking up:
	if the location is uncovered, try examining the sky;
	otherwise say "You don’t like ceilings. They make you feel claustrophobic."

Section 5 - Passing of time

[Here we use the scene paradigm for altering descriptions nearer dawn (some here, some later). Actually, no-one should spend this long in the game, but the machinery is here in case we have a player who isn't easily bored.]

Night-Time is a scene. Night-Time begins when play begins. Night-Time ends when the time of day is 4:00 AM. 

When Night-Time begins:
	now the description of the sky is "There is nothing above you but velvety blackness, studded with glittering stars and a conspiratorial full moon."

Pre-Dawn is a scene. Pre-Dawn begins when Night-Time ends. Pre-Dawn ends when the time of day is 5:00 AM.

When Pre-Dawn begins:
	say "You sense a change of atmosphere: you can’t quite put your finger on it, but the zoo doesn’t seem quite so [italic type]still[roman type] any more. It must be nearing dawn: you’d better hurry.";
	now the description of the sky is "Directly above, the sky is blue-black with a few bright stars persisting to observe your progress. As you look east, it pales to a dark blue."
	
Dawn is a scene. Dawn begins when Pre-Dawn ends. Dawn ends when the time of day is 6:00 AM.

When Dawn begins:
	say "The pervasive quiet you have experienced so far has started to give way to the gentle rustling of the zoo waking from its slumbers. In the distance, you can hear the first bird calls of the morning, and just on the edge of your hearing is the faint rumbling of traffic. It won’t be long before the keepers arrive.";
	now the description of the sky is "A solitary star remains in the dark blue sky. Dawn is breaking in the east."

When Dawn ends:
	if the location is Your Stall or the location is Affero's Stall:
		say "As if from nowhere, your keeper Lee appears. 'Good morning!' he says, chirpily. 'Sleep well?'";
		end the story saying "There is no escape.";
	otherwise:
		say "As if from nowhere, your keeper Lee appears. 'There you are! I’ve been looking for you everywhere,' he says. 'Let’s get you back to your enclosure.'";
		end the story saying "There is no escape."

Section 6 - The Herd

[These rules are for implementing the herd the player must assemble.]

A gnu is a kind of animal.

Instead of taking an animal:
	say "Kidnapping isn't your style. Have you tried asking [if the noun is male]him[otherwise if the noun is female]her[otherwise]it[end if] to follow you?"

The list of followers is a list of gnus that varies.

Following is an action applying to one thing. Understand "follow [something]" as following.

Persuasion rule for asking animals to try following: persuasion succeeds.

Instead of following something:
	if the noun is the player:
		say "While chasing your own tail was fun when you were little, you’d feel silly doing it now.";
	otherwise:
		say "You wait for [the noun] to move, but [the noun] doesn’t seem to be going anywhere.";
	try silently waiting.

Before someone following:
	if the actor is not touchable:
		say "[The actor] can’t even get to where you are now, let alone follow you." instead.

Check someone following:
	if the noun is the actor:
		say "As much as you would enjoy seeing [the actor] chasing [if the actor is male]his[otherwise if the actor is female]her[otherwise]its[end if] own tail, you don’t think [if the actor is male]he[otherwise if the actor is female]she[otherwise]it[end if] would go for it." instead;
	otherwise if the actor is not a gnu:
		say "You try to get your message across, but [the actor] just stares at you as if you’re bonkers." instead;
	otherwise if the noun is not the player:
		say "[The actor] gives you a withering look. You wither and apologise for being silly." instead;
	otherwise if the actor is listed in the list of followers:
		say "[The actor] is already following you." instead.

Unsuccessful attempt by someone following: do nothing.

Carry out someone following:
	add the actor to the the list of followers;
	now the actor is undescribed;
	increase the score by 1;

Report someone following:
	say "[The actor] has joined your herd.";
		
Stopping following is an action applying to one thing. Understand "stop following [something]" as stopping following.

Instead of stopping following something:
	say "You steel yourself for action. Yes, you are a leader, not a follower."

Check someone stopping following:
	if the noun is the actor:
		say "Yes, that’s quite enough tail-chasing." instead;
	otherwise if the actor is not listed in the list of followers:
		say "[The actor] isn’t following [the noun] at the moment." instead;
	otherwise if the noun is not the player:
		say "[The actor] isn’t following [the noun] at the moment." instead.

Unsuccessful attempt by someone stopping following: say nothing.

Carry out stopping following:
	remove the actor from the the list of followers;
	decrease the score by 1.

Report stopping following:
	say "[The actor] looks a little upset to be ejected from your herd. Won’t you reconsider?".

After taking inventory:
	if the list of followers is non-empty:
		say "You are being followed by [the list of followers with definite articles]."

After going a direction:
	repeat with the follower running through the list of followers:
		move the follower to the location;
	continue the action.

Understand "stroke [something]" as touching. Understand "kiss [something]" as touching. Understand "nuzzle [something]" as touching. Understand "lick [something]" as touching.

Understand "mounting [something]" as a mistake ("You have relatives who have been stuffed and mounted, and would not wish that on anyone else.").

Section 7 - Out of this world

After printing the banner text:
	say "Type HELP for help, and ABOUT for a little background."

Rule for amusing a victorious player: say "I hope you enjoyed that.[paragraph break]You worked out, I expect, that this game is a thinly-veiled tutorial on software licence compatibility. It should be fairly obvious that the character you play represents the GNU General Public Licence; that it’s version 3, maybe less so. But did you work out which licences the other twelve residents of the zoo represent? (For hints, see http://www.gnu.org/licenses/license-list.html.)[paragraph break]You might also want to look out for the four possible ways to lose the game. But probably not."

Helping is an action out of world applying to nothing. Understand "help" as helping. Report helping:
	say "If you are unfamiliar with playing these sorts of games, there’s a great cheat-sheet at http://pr-if.org/doc/play-if-card/. But the kinds of commands you need to know in order to play this game are:[line break]* GO NORTH or NORTH or N (etc.)[roman type][line break]* IN, OUT[line break]* EXAMINE (thing) or X (thing), TOUCH (thing)[line break]* TAKE (thing), DROP (thing), THROW (thing) AT (target)[line break]* UNLOCK (door) WITH (key)[line break]* INVENTORY or I − (tells you what you are holding)[line break]* SAVE, RESTORE − (in case you don’t manage it in one sitting)[line break]* UNDO[line break]* PETER, FOLLOW ME − (that is, to ask someone to do something, type their name, then a comma, then the instruction).[paragraph break]As a general tactic, you will find that examining things helps in many cases. Do you need more advice on what to do?[line break][command prompt]";
	if the player consents:
		say "The primary objective here is to escape the zoo. The secondary objective is to help the others to escape, but don’t get too hung up on that, because there’s only so much you can do for them.[paragraph break]The thing is, you can’t escape on your own: you need help. And the only animals that speak your language are other gnus (and even then, it’s late at night, everyone’s sleepy, so you’ll have to keep it very simple). And, sorry to say, there just aren’t enough gnus in the zoo. Once you’ve figured your way around that little problem, it should be (mostly) plain sailing.[paragraph break]If you’re still not sure what you should be doing, here are some pointers.[line break]* Have you asked the gnu next door to do something? (See above for how to do that.)[line break]* Have you found and examined some keys?[line break]* Have you tried stroking or waking up a cat?[line break]* The aviary is the most difficult bit: leave it till last.[paragraph break]Good luck!";
	otherwise:
		say "That’s the spirit. Good luck!"

Abouting is an action out of world applying to nothing. Understand "about" as abouting. Report abouting: say "The inspiration for this game came from two sources, really.[paragraph break]First was the set of four mini-games written for the TuxRadar podcast: see http://tuxradar.com/content/podcast-season-2-episode-18. You will probably be able to detect elements of at least three of those games in this one.[paragraph break]The other was some work I did in the latter half of 2010 on data licensing. This game is nothing to do with data licensing, but the connection will hopefully become clear.[paragraph break]Special thanks go to Barbara Ball and Chris Ball for testing the game for me."

Chapter 2 - Gnu Enclosure

When play begins:
	now the time of day is 12:00 AM;
	move the sky backdrop to all uncovered rooms;
	say "The powerful sun radiating down from the endless blue sky. Vast empty wilderness for as far as the eye can see. Running through the glorious scrubby grasslands, running, running, running free…[paragraph break]The flash of a patent leather boot. A net coming down over your head. Cold. Why is it suddenly so very cold?"

Section 1 - Your Stall

Your Stall is a covered room. "[if unvisited]You jerk await. It really [italic type]is[roman type] cold. Okay, your stall is draughty at the best of times, but tonight… You drag yourself to your hooves and poke your head out.[paragraph break]That’s odd: the gate is open. Your keeper, Lee, would never leave the gate open. Then you remember: Lee didn’t tuck you in last night, it was that new stallman − sorry, junior keeper. You thought there was something shifty about him. No matter. A night of exploration awaits.[paragraph break][end if]Your stall is wooden structure lined with straw. It smells a little unpleasant. Another stall lies to the west, and the rest of your enclosure lies to the north and east."

Your straw is an object in Your Stall. "Reassuringly scratchy and warm, but it could do with changing." It is scenery.

Instead of taking your straw:
	say "Though it is not exactly fixed in place, there's no way you can carry it. It would soon get soggy in your mouth."

Instead of going nowhere from Your Stall:
	if the noun is outside:
		try going south;
	otherwise:
		say "You’ve already memorized every inch of this enclosure. Why waste time wandering around in here?"

After going south from Your Stall for the first time:
	say "You experience a frisson of excitement stepping through the gate and out into forbidden territory.";
	continue the action.

Section 2 - Affero's Stall

Affero's Stall is a covered room. "This stall is almost identical to yours, except it is slightly untidier but smells somewhat sweeter. Your stall lies back to the east." It is west of Your Stall.

Affero the Gnu is a female gnu. "Curled up in the stall is the sleeping form of Affero, a fellow gnu. Apparently she’s something of a poster child for the zoo, with her own website and webcam. Looking at the silky threads that infest the upper corners of the stall, you can believe it.[paragraph break]Affero stirs to wakefulness as you approach." The description of Affero is "She’s a gnu. Agnother gnu. You'd be thrilled if she’d consent to follow you. Even in the dark you see she’s gno tsessebe. Oh, gno, gno, gno, she’s a gnu." She is in Affero's Stall.

The webs are an object in Affero's Stall. "The webs are heavy with dirt and grime." They are scenery. Understand "silky threads" as the webs.

After Affero following the player:
	now the description of Affero is "She’s a gnu. Agnother gnu. And you’re really glad she’s come along with you.";
	continue the action.

After Affero stopping following the player:
	now the description of Affero is "She’s a gnu. Agnother gnu. And you’d rather she resumed her walk with you.";
	continue the action.

Section 3 - The river

The river is backdrop with description "The river looks and smells fresh and clean, and gurgles in a quietly happy sort of way."

Instead of listening to the river, say "The river babbles and gurgles in a quietly happy sort of way."

Instead of touching the river, say "Stooping down, you dip your nose in the water. It is bitterly cold."

Instead of drinking the river:
	say "You lap at the icy water. It is refreshing, but if you have too much you’ll get a headache."

Understand "water" as the river. Understand "stream" as the river. Understand "from river" as the river.

Section 4 - Entrance

The Gnu Enclosure Entrance is a room. "You are standing on the yellow grit path that runs to the south of your enclosure. The path winds towards you from the west and continues to the east, interrupted only by a broad wooden bridge spanning a gently flowing river. The river runs along the eastern border of your enclosure and continues babbling south; another path breaks off to follow it."

The grit path is backdrop with description "The path is gritty, no doubt hard-wearing but a bit rough on the old hooves.". Understand "yellow grit path" as the grit path. Understand "yellow path" as the grit path. It is in the Gnu Enclosure Entrance.

The wooden bridge is an object in the Gnu Enclosure Entrance. "The bridge is solidly constructed and in good repair." It is scenery.

The river is in the Gnu Enclosure Entrance.

The gnu enclosure gate is a door. "The gate to the gnu enclosure lies [if open]open[otherwise]closed[end if] to the [direction of the gnu enclosure gate from the location]." It is openable, open, lockable and unlocked. It is south of Your Stall and north of the Gnu Enclosure Entrance. The black key unlocks the gnu enclosure gate.

After locking the gnu enclosure gate with something for the first time:
	decrease the score by 1;

Instead of going nowhere from the Gnu Enclosure Entrance when the noun is inside, try going north.

After going west from the Gnu Enclosure Entrance for the first time:
	say "You wander westward along the path. It rises to an observation platform overlooking another enclosure; you peek in[if Night-Time is happening] but can see very little in the moonlight[otherwise if Pre-Dawn is happening] but can see very little in this strange half-light[otherwise], and can just make out a family of lions dopily rousing themselves over at the far side of the enclosure[end if]. You decide to press on, past an inconveniently placed sign in the middle of the path, down a gentle incline, and round to the enclosure gate.";
	increase the time of day by ten minutes;
	continue the action.

After going west from the Gnu Enclosure Entrance at least twice:
	say "You trot back over the observation platform and down the slope.";
	increase the time of day by ten minutes;
	continue the action.

After going east from the Gnu Enclosure Entrance for the first time:
	say "You head off eastward along the path. Your hooves make a loud clip-clip sound as you cross the bridge; [one of]you pause for a moment and look around, but can see no sign of attracted attention[or]you idly consider trying out a tap routine, but dismiss the idea almost at once[stopping]. Shrugging, you continue along the path and soon another enclosure comes into view. The first you see of it is a large grassy area dotted with harassed-looking trees, but following the path round to its end you discover a concrete area dominated by a large steel shelter.";
	increase the time of day by ten minutes;
	continue the action.

After going east from the Gnu Enclosure Entrance at least twice:
	say "You head off over the bridge and around the bend again.";
	increase the time of day by ten minutes;
	continue the action.

After going south from the Gnu Enclosure Entrance:
	say "You turn the corner in the path and follow the susserating stream southwards.";
	increase the time of day by five minutes;
	continue the action.

Chapter 3 - Rest of Africa Zone

Section 1 - Lion Enclosure

The Lion Enclosure Entrance is a room. "You stand at the entrance of the lion enclosure. A strong, high fence separates you from the dangers lurking within. One of whom[if the Lion Enclosure Entrance is unvisited], you realise with a start,[end if] is standing there looking at you through the gate. A path rises back eastwards to an observation platform and beyond.[paragraph break]Being this close to one of your natural predators fills you with unease." It is west of the Gnu Enclosure Entrance.

The Lion Enclosure Itself is a room. "[unless Dawn is happening]It’s hard to make out much in this light. [end unless]It's bumpy. There’s a ragged pool float hanging from a tree. And, bizarrely, beautifully intricate carvings everywhere. The thing that most completely captivates your attention, though, is the stench of Tex the Lion’s breath. It carries easily over to you in the [if Night-Time is happening]cool night[otherwise]crisp early-morning[end if] air. Unmistakably, raw meat." Index map with the Lion Enclosure Itself mapped west of the Lion Enclosure Entrance.

The Lion Enclosure Entrance is connected with the Lion Enclosure Itself.

The lion enclosure gate is inside of the Lion Enclosure Entrance and outside of the Lion Enclosure Itself. It is a door and scenery. It is lockable and locked. The description of the lion enclosure gate is "The enclosure’s gate is made up of closely spaced bars and a reinforced box housing the lock mechanism." The yellow key unlocks the lion enclosure gate.

The lion enclosure fence is a backdrop with description "The fence is a tough-looking mix of steel bars and chain-link, reaching up a good twelve feet." It is in the Lion Enclosure Entrance and the Lion Enclosure Itself.

Tex the Lion is an animal with description "Tex is sleek, powerful, and if you read his expression correctly, really quite hungry." He is in the Lion Enclosure Itself. He is undescribed. Understand "lion" as Tex the Lion.

The grit path is in the Lion Enclosure Entrance.

The observation platform is an object in the Lion Enclosure Entrance. "A broad wooden platform to the side of the path, affording a good view over the enclosure[if Night-Time is happening], though there is not much to see at this time of night[end if]." It is scenery.

The ragged pool float is an object in the Lion Enclosure Itself. "It would probably not float any more, given how it is punctuated with bite marks." It is scenery.

The intricate carvings is an object in the Lion Enclosure Itself. "You recognise the style, but can't place it." They are scenery.

After unlocking the lion enclosure gate with the yellow key:
	say "Tex chooses that moment to yawn and lick his lips.";
	continue the action.

After opening the lion enclosure gate:
	say "The gate swings open with an ominous creak. Tex looks you up and down; a single strand of drool escapes from his lips. You hardly have chance to back away before he leaps through the gateway, all teeth and claws. In a final moment of detachment, you muse that the service you were aiming to provide was escape, not breakfast in bed.";
	end the story saying "Tex's mouth and stomach are no mystery to you now."

[The player should never get this far]
Instead of touching Tex the Lion:
	say "You are distracted by a cloud of bugs that begin to buzz around you. A few swishes of your tail is sufficient to move them on, but the experience leaves you shuddering."

After going east from the Lion Enclosure Entrance for the first time:
	say "You retreat back eastwards, nearly tripping over that obstructive sign. Such is your relief at leaving those slavering jaws behind, you don't even glance back down into the lion enclosure as you pass the observation platform. Soon the strangely reassuring sight of your own enclosure comes into view.";
	increase the time of day by ten minutes;
	continue the action.

After going east from the Lion Enclosure Entrance at least twice:
	say "You retreat back eastwards until the reassuring sight of your own enclosure comes into view.";
	increase the time of day by ten minutes;
	continue the action.

Section 2 - Elephant Enclosure

The Elephant Enclosure Entrance is a room. "You stand before the gate of the elephant enclosure. Through the fence and you see a wide concrete floor decorated with closed metal skips and dominated by a large steel shelter. Your nostrils recoil from a pungent mix of sweat, dung and over-ripe fruit." It is east of the Gnu Enclosure Entrance.

The Elephant Enclosure Itself is a room. "The area in front of you could best be described as Vincent’s bedroom and bathroom. Beyond it lies a small, scrubby park in which you imagine he whiles away the daytime." Index map with the Elephant Enclosure Itself mapped east of the Elephant Enclosure Entrance.

The Elephant Enclosure Entrance is connected with the Elephant Enclosure Itself.

The elephant enclosure gate is inside of the Elephant Enclosure Entrance and outside of the Elephant Enclosure Itself. It is a door and scenery. It is lockable and locked. The description of the elephant enclosure gate is "The enclosure’s gate is made up of closely spaced bars and a reinforced box housing the lock mechanism." The white key unlocks the elephant enclosure gate.

The elephant enclosure fence is a backdrop with description "The fence is light chain-link, not unlike that surrounding your enclosure." It is in the Elephant Enclosure Entrance and the Elephant Enclosure Itself.

The skips are objects in the Elephant Enclosure Itself. "They are big metal bins with lids, presumably for storing food or waste. They are not very interesting." They are scenery.

The large steel shelter is an object in the Elephant Enclosure Itself. "The shelter surrounds Vincent on three sides with walls of steel, as well as providing him with a roof. It is lined with straw as bedding." It is scenery.

Vincent's straw is an object in the Elephant Enclosure Itself. "You are familiar enough with straw bedding from your own stall, and feel no need to investigate further." It is scenery.

Instead of taking the straw:
	say "Though it is not exactly fixed in place, there's no way you can carry it. It would soon get soggy in your mouth."

The scrubby park is backdrop with description "A wide open space dotted with harassed-looking trees." It is in the Elephant Enclosure Itself.

The trees are an object in the Elephant Enclosure Itself. "Basically oversize scratching posts for Vincent." They are scenery.

Vincent the Elephant is an animal in the Elephant Enclosure Itself. "Under the shelter, Vincent the Elephant lies fast asleep." The description of Vincent the Elephant is "Vincent is a pretty huge pachyderm. Seeing him parked here peacefully, you couldn’t imagine him doing anyone any harm, but you wouldn’t want to get on the wrong side of him in a fight." He is asleep.

Instead of touching Vincent the Elephant:
	say "Vincent’s skin is dry and rough. You feel suave in comparison."

[Rather than count attempts, we count the number of times a would-be successful attempt is aborted.]
The number of elephant prods is a number that varies.

Instead of waking Vincent the Elephant:
	increment the number of elephant prods;
	say "You poke him playfully, but Vincent remains impervious to your prodding. You don’t like to try too hard, in case he wakes up grumpy."

Instead of waking Vincent the Elephant when the number of elephant prods is 2:
	say "Throwing caution to the wind, you jab Vincent hard with your horns. With an enormous bellow, his head jerks up, terror in his tiny eyes. It takes you a few seconds to realise that, in so doing, Vincent has accidentally impaled you on one of his long white tusks. Bugger.";
	end the story saying "Fatal error: Vincent took exception."

After going west from the Elephant Enclosure Entrance for the first time:
	say "You retreat back along the outside of the elephant enclosure. Pausing on the bridge, you glance down at the gurgling waters below[if Night-Time is happening]; you catch the odd glint of reflected starlight, but nothing more[otherwise if Pre-Dawn is happening], at the turbulent surface glimmering mesmerically in the twilight[otherwise]as they flash with ominous glints of reflected red light from the dawning sun[end if]. Best move on.";
	increase the time of day by ten minutes;
	continue the action.

After going west from the Elephant Enclosure Entrance at least twice:
	say "You trip-trap back over the bridge towards your own enclosure.";
	increase the time of day by ten minutes;
	continue the action.

Chapter 4 - General areas

Section 1 - Riverside

The Riverside is a room. "You come to a crossroads of sorts. A path runs north and south along the western bank of the river, while another runs off to the west.[paragraph break]Between the north and west paths is a large wooden hut. It has a solid, permanent look about it. The windows are covered in wire mesh; you can see nothing through them. [if the Keeper's Hut is unvisited]On the plus side, the[otherwise]The[end if] door has been wedged open[if the Keeper's Hut is unvisited]. (Curious.) There’s a sign on the door which, of course, you can’t read, but as the door smells slightly of Lee, you imagine it might have something to do with him[end if]." It is south of the Gnu Enclosure.

The river is in the Riverside. The grit path is in the Riverside.

[Surrogate object representing the outside of the Keeper's Hut]
The large wooden hut is scenery in the Riverside. "The outside is rather plain. But what’s inside?"

Understand "hut" as the large wooden hut. Understand "wooden hut" as the large wooden hut. Instead of entering the large wooden hut, try going inside.

The windows are an object in the Riverside. "Despite some strained peering, you can still see nothing through the window." They are scenery. Understand "mesh" as the window.

The door sign is an object in the Riverside. "Black squiggles on a white background." It is scenery.

After going north from the Riverside:
	say "You follow the susserating stream northwards, past a sign bearing an outline of Africa, until you come to a T-junction in the path. The nearest landmark is a little to the west, so you go that way.";
	increase the time of day by five minutes;
	continue the action.

After going south from the Riverside:
	say "You follow the river south. It is not long before the river comes to its end in a large pond, which itself drains through a weir into a lake stretching out to the west. You proceed along the path over the weir.";
	increase the time of day by five minutes;
	continue the action.	

After going west from the Riverside:
	say "You follow the westwards path past a sign bearing an outline of Australia. The first enclosure soon comes into sight.";
	increase the time of day by five minutes;
	continue the action.

Instead of going nowhere from the Riverside when the noun is northwest, try going inside.

Section 2 - The Keeper's Hut

The Keeper's Hut is a room. "Lee keeps his office very tidy. You were expecting a dirty mug, at least." It is inside of the Riverside. Index map with the Keeper's Hut mapped east of Your Stall.

Instead of going nowhere from the Keeper's Hut when the noun is southeast, try going outside.

[I had some trouble with the bunch of keys. I wanted a whole−part relationship, but you can't use a component as a key. I also wanted some realism: a gnu can only carry things in its mouth, so I didn't want to allow more than one item to be carried at once. But if we model the bunch of keys as a tray, the gnu would have to carry both the keyring and the key in use at once, which I've disallowed. Below is my less-than-elegant solution.]

The keyring is an object in the Keeper's Hut. "You can see a bunch of keys here." The description of the keyring is "There is a black, a white, a red, a green, a yellow and a brown key, all attached to an enormous steel hoop."

Understand "bunch of keys" as the keyring. Understand "keys" as the keyring. Instead of unlocking something with the keyring, say "You need to specify the key you want to use: the black key, the white key, the red key, the green key, the yellow key or the brown key."

After taking the keyring:
	now the black key is held by the player;
	now the yellow key is held by the player;
	now the white key is held by the player;
	now the red key is held by the player;
	now the green key is held by the player;
	now the brown key is held by the player;
	say "You clamp your jaws around the keyring and heft it into the air, keys jangling beneath. Tastes nasty, but bearable."

After dropping the keyring:
	now the black key is in the location;
	now the yellow key is in the location;
	now the white key is in the location;
	now the red key is in the location;
	now the green key is in the location;
	now the brown key is in the location;
	continue the action.

After inserting the keyring into something:
	now the black key is inside the noun;
	now the yellow key is inside the noun;
	now the white key is inside the noun;
	now the red key is inside the noun;
	now the green key is inside the noun;
	now the brown key is inside the noun;
	continue the action.

After putting the keyring on something:
	now the black key is on the noun;
	now the yellow key is on the noun;
	now the white key is on the noun;
	now the red key is on the noun;
	now the green key is on the noun;
	now the brown key is on the noun;
	continue the action.

[We will use these to model throwing the keyring later.]
To dropKeyring:
	now the black key is in the location;
	now the yellow key is in the location;
	now the white key is in the location;
	now the red key is in the location;
	now the green key is in the location;
	now the brown key is in the location;
	continue the action.

To loseKeyring:
	remove the black key from play;
	remove yellow key from play;
	remove white key from play;
	remove red key from play;
	remove green key from play;
	remove brown key from play;
	continue the action.

The black key is an object with description "The bow of this key has been enamelled black. It is a slightly odd shape, with two pointy bits that look a bit like horns." It is in the Keeper's Hut. It is undescribed.

Instead of taking the black key, try taking the keyring. Instead of dropping the black key, try dropping the keyring. Instead of inserting the black key into something, try inserting the keyring into the noun. Instead of putting the black key on something, try putting the keyring on the noun. Instead of throwing the black key at something, try throwing the keyring at the second noun.

The yellow key is an object with description "The bow of this key is mainly solid, with a hole for the keyring in one corner. A piece of yellow, furry material has been stuck around it." It is in the Keeper's Hut. It is undescribed.

Instead of taking the yellow key, try taking the keyring. Instead of dropping the yellow key, try dropping the keyring. Instead of inserting the yellow key into something, try inserting the keyring into the noun. Instead of putting the yellow key on something, try putting the keyring on the noun. Instead of throwing the yellow key at something, try throwing the keyring at the second noun.

The white key is an object with description "The bow and half the shaft of this key have been coated in white plastic, or possibly enamel, and made to look like ivory." It is in the Keeper's Hut. It is undescribed.

Instead of taking the white key, try taking the keyring. Instead of dropping the white key, try dropping the keyring. Instead of inserting the white key into something, try inserting the keyring into the noun. Instead of putting the white key on something, try putting the keyring on the noun. Instead of throwing the white key at something, try throwing the keyring at the second noun.

The red key is an object with description "The bow of this key has been enamelled red. It is a slightly odd shape, with two pointy bits that look a bit like horns." It is in the Keeper's Hut. It is undescribed.

Instead of taking the red key, try taking the keyring. Instead of dropping the red key, try dropping the keyring. Instead of inserting the red key into something, try inserting the keyring into the noun. Instead of putting the red key on something, try putting the keyring on the noun. Instead of throwing the red key at something, try throwing the keyring at the second noun.

The green key is an object with description "This is one of the smaller keys. At one point the whole thing was painted green, but the paint has worn off most of the blade. Some wag has drawn little semicircles on it to resemble scales." It is in the Keeper's Hut. It is undescribed.

Instead of taking the green key, try taking the keyring. Instead of dropping the green key, try dropping the keyring. Instead of inserting the green key into something, try inserting the keyring into the noun. Instead of putting the green key on something, try putting the keyring on the noun. Instead of throwing the green key at something, try throwing the keyring at the second noun.

The brown key is an object with description "This is one of the smaller keys. Its bow has been coated with a material that looks brown from a distance, but on closer inspection the colour is built up from flecks of all sorts of different earth tones. It has a feathery texture." It is in the Keeper's Hut. It is undescribed.

Instead of taking the brown key, try taking the keyring. Instead of dropping the brown key, try dropping the keyring. Instead of inserting the brown key into something, try inserting the keyring into the noun. Instead of putting the brown key on something, try putting the keyring on the noun. Instead of throwing the brown key at something, try throwing the keyring at the second noun.

After unlocking something with something:
	say "It takes a bit of oral dexterity, but after juggling the bunch of keys you manage to grip [the second noun] between your lips, manoeuvre it into the lock and give it a twist. There is a satisfying click."

Section 2 - Lakeside

The Lakeside is a room. "The pathway on which you stand is bounded by low stone walls as it runs over a weir. The weir separates the pond to the northeast from the lake that expands away, at a lower level, to the southwest. The path runs north, following the river that feeds the pond, and south to a wide paved area. You can see another path running west which would have remained inconspicuous had some fool not seen fit to stick a sign in the middle of it." It is south of the Riverside.

The grit path is in the Lakeside.

The stone walls are objects in the Lakeside. "Some effort has gone into making these walls aesthetic as well as functional. The design incorporates numerous small holes, perhaps to allow the human juveniles to look − but not fall − through. They still smell remarkably clean." They are scenery. Understand "holes" as the stone walls.

The weir is an object in the Lakeside. "You can’t get a clear view of the weir from here." It is scenery.

The pond is an object in the Lakeside. "It’s about the right size to house, say, representatives of three duck species, though none are in evidence at this time of [if Night-Time is happening]night[otherwise]the morning[end if]." It is scenery.

The lake is backdrop. "The lake stretches serenely away into the distance, making gentle lapping sounds." It is in the Lakeside.

The river is in the Lakeside.

The no-entry sign is an object in the Lakeside. "You can’t read the sign, of course, but it has a sort of formality about it that would encourage visitors to go elsewhere for entertainment." It is scenery.

The park bench is a supporter. "A park bench has been positioned nearby to provide any occupants with an excellent view of the lake[if Tabby the Cat is on the park bench]. The zoo’s cat, Tabby, lies asleep on it, quietly snoring[end if]." The description of the park bench is "It’s a plain, slatted wooden bench, about as long as you are, facing towards the lake. It smells like it was recently varnished." It is in the Lakeside.

Tabby the Cat is a female animal with description "Tabby by name, tabby by nature." She is on the park bench. She is undescribed and asleep.

Tabby the Gnu is a female gnu with description "She’s a gnu. Agnother gnu. The only one alive who’s known to mew."

Instead of waking Tabby the Cat, try touching Tabby the Cat.

Instead of touching Tabby the Cat:
	remove Tabby the Cat from play;
	now Tabby the Gnu is in the Lakeside;
	increase the time of day by five minutes;
	say "You nudge the cat with your nose, but immediately spring back with a stinging snout. Tabby is standing, hissing at you, hackles raised and back arched. A blue glow surrounds her as she starts to grow; soon she is forced off the bench onto the path. Her fur becomes coarser and darker. With a sickening tearing sound, horns force their way out of her head, and hooves burst from her paws.[paragraph break]Scant moments later, the glow fades. Tabby the Cat is no more and Tabby the Gnu stands in her place."
	
After going north from the Lakeside:
	say "You make your way off the weir, past the pond, and north along the river.";
	increase the time of day by five minutes;
	continue the action.

After going west from the Lakeside:
	say "You carefully pick your way past the sign, mentally tutting to yourself as you do so, and follow a gravel path bordered by hedges.";
	increase the time of day by five minutes;
	continue the action.

After going south from the Lakeside:
	increase the time of day by two minutes;
	continue the action.

Instead of going nowhere in the Lakeside when the noun is inside:
	try going east.

Section 3 - Main Concourse

The Main Concourse is a room. "You are in the middle of a large paved area bounded by water features to the north and buildings on the remaining three sides. The buildings have been shuttered and boarded up for the night.[paragraph break]A path runs over a weir to the north." It is south of the Lakeside.

The lake is in the Main Concourse. Understand "water features" as the lake.

The shops are objects in the Main Concourse. "From the pictures on the signs above them, there appears to be at least a gift shop and a café here. They are, however, securely shuttered and boarded up." They are scenery. Understand "buildings" as the shops.

After deciding the scope of the player:
	if the location is the Main Concourse, place the weir in scope.

The clock tower is an object in the Main Concourse. "You are by no means expert at interpreting these human timepieces, but your best guess is that it reads [the time of day to the nearest five minutes in words]." It is scenery.

[Surrogate object representing outside of aviary]
The aviary is a container in the Main Concourse. "It is a sizeable wooden building with a glass door at the northern end. The walls are adorned with boards shaped and painted as birds of prey." It is scenery. Instead of entering the aviary, try going west.

Instead of going nowhere from the Main Concourse when the noun is inside:
	try going west.

[This changes the default error message for trying to touch things made visible in the above way.]
Rule for reaching inside a room: 
    say "You can only look from this distance."; 
    deny access.

After going north from the Main Concourse:
	increase the time of day by two minutes;
	continue the action.

After going east from the Main Concourse:
	say "You proceed through the archway.";
	increase the time of day by two minutes;
	continue the action.

After going west from the Main Concourse:
	increase the time of day by two minutes;
	continue the action.

Chapter 5 - Oceania Zone

[Tasmanian Devil, in case you were worried.]
The Devil Enclosure Entrance is a room. "You stand before the gate of a small enclosure that looks more like a rockery garden. The path runs east to west here, but further progress westwards has been made impossible by a cattle grid. Which is a shame, really, as you’ve heard there are kangaroos and wombats down this way.[paragraph break]In the middle of the enclosure is large stone jutting out the ground at a shallow angle.[if Beastie the Big Scary Devil is in the Devil Enclosure Itself] Collapsed in front of this is Beastie.[end if]". It is west of the Riverside.

The cattle grid is scenery in the Devil Enclosure Entrance. "Annoying and impassable."

Jumping over is an action applying to one thing. Understand "jump over [something]" as jumping over. Instead of jumping over the cattle grid, say "Don’t be ridiculous, you don’t have Super Cow Powers. You’d break a leg." Check jumping over: say "Only cows attempt stunts like that." instead.

The Devil Enclosure Itself is a room. "The interior of the enclosure strongly resembles a rockery garden. It is dominated by a large stone positioned at its centre. The stone juts out of the ground at a shallow angle; nothing but shadows are visible beneath, though it smells of sleeping quarters." Index map with the Devil Enclosure Itself mapped west of the Devil Enclosure Entrance.

The Devil Enclosure Entrance is connected with the The Devil Enclosure Itself.

The devil enclosure gate is inside of the Devil Enclosure Entrance and outside of the Devil Enclosure Itself. It is a door and scenery. It is lockable and locked. The description of the devil enclosure gate is "The gate is not as sturdily built as some you have seen, but still solid enough to do its job." The red key unlocks the devil enclosure gate.

[This is a bit of a hack.]
Understand "large stone" as the Devil Enclosure Itself.

Beastie the Big Scary Devil is an animal. "Beastie is quite possibly the largest and fiercest Tasmanian Devil in the world, though still much smaller than you. Nevertheless, such is his reputation that visitors call him the Big Scary Devil. At the moment, though, he looks rather [state of Beastie]." The description of Beastie the Big Scary Devil is "Looking more closely at the devil, you identify the source of his distress: there are small white lumps embedded in his side." He is in the Devil Enclosure Itself. Understand "devil" as Beastie the Big Scary Devil. Understand "Tasmanian Devil" as Beastie the Big Scary Devil. 

The claws are an object in the Devil Enclosure Itself. They are undescribed. The description of the claws is "They appear to be claws. The claws of some adverse tiger, you think, though you have no idea how they came to be stuck in the devil’s hide." The indefinite article of the claws is "some". Understand "small white lumps" as the claws. Understand "white lumps" as the claws. Understand "lumps" as the claws.

To say state of Beastie:
	if the claws are undescribed:
		say "poorly";
	otherwise:
		say "dopey".

Understand "extract [something] from Beastie" as taking. Understand "extract [something]" as taking. Understand "pluck [something] from Beastie" as taking. Understand "pluck [something]" as taking.

Instead of removing the claws from Beastie the Big Scary Devil, try taking the claws. Understand "remove [something]" as taking.

Before taking the claws:
	if the claws are undescribed:
		if the keyring is held:
			say "You put down the bunch of keys and approach Beastie carefully.";
			silently try dropping the the keyring;
		otherwise:
			say "You approach Beastie carefully."

After taking the claws when the claws are undescribed:
	now the claws are described;
	now the printed name of Beastie the Big Scary Devil is "Beastie the mollified Big Scary Devil";
	now the description of Beastie the Big Scary Devil is "As well as the normal scents of sweat, dust and insufficient dental hygiene, Beastie smells strongly of blood. A dark stain on his fur reveals the location of the wound.";
	say "He half-heartedly snaps his powerful jaws at you, but you dodge them easily. Bending down, you clamp your teeth around the first claw and yank it out. Beastie yelps and squirms, but soon settles again. You remove the remaining claws with much the same result, then retreat to a safe distance. It would be an exaggeration to say Beastie looks grateful, but he does seem mollified.";
	silently try dropping the claws;
	now the description of the claws is "They appear to be the claws of some adverse tiger, and are somewhat stained with Beastie's blood.".

Beastie the Gnu is a gnu with description "He’s a gnu. Agnother gnu, with teeth so sharp it hurts his mouth to chew."

Instead of touching Beastie the Big Scary Devil:
	if the printed name of Beastie the Big Scary Devil is "Beastie the mollified Big Scary Devil":
		remove Beastie the Big Scary Devil from play;
		now Beastie the Gnu is in the Devil Enclosure Itself;
		increase the time of day by five minutes;
		say "Tentatively, you edge closer to the Tasmanian devil and nudge him with your hoof. His shriek and a sharp pain in your leg makes you instantly step back. Beastie lets out a deafening screech as a blue haze overtakes him. He shudders violently, visibly growing with every spasm. There are unpleasant crunching sounds as his bones break and reset; it must be excruciating.[paragraph break]The transformation takes a while to complete, but eventually the haze disperses, leaving an exhausted Beastie standing in front of you, no longer a devil, but a gnu like yourself.";
	otherwise:
		say "You inch towards Beastie, but he snaps his jaws at you in warning. Perhaps you ought to attend to what ails him first."

After going east from the Devil Enclosure Entrance:
	increase the time of day by five minutes;
	continue the action.

Chapter 6 - Stores

The Storage Area is a room. "You emerge into what is clearly a backstage area of the zoo. There are silos containing different types of food, and various smaller containers used to transport it to the different enclosures." It is west of the Lakeside.

The silos are closed containers in the Storage Area. "These large metal cylinders tower over you. There are round hatches set in their sides, securely fastened. Which is a shame, as the hatches emit a tantalisingly appetising aroma." They are scenery.

The hatches are part of the silos. The description of the hatches is "The hatches are tightly shut, and you can find no way to open them."

Instead of smelling the silos, say "You can detect hay, silage, various forms of grain and − could it be? − toasted pine kernels! Lovely. You can never have enough kernels."

Instead of opening the silos, say "You nibble around the hatches but you can find no way to open them."

The smaller containers are closed containers in the Storage Area. "They are general purpose tubs, not particularly interesting apart from the aroma of food. Sniffing them, you are sure you can identify at least eight different varieties of bran. Hmm, is that bran nine?" They are scenery.

Instead of opening the smaller containers, say "You nibble around the lids but you can find no way to open them."

Glenda the Rabbit is a female animal. "This area is bounded to the west by a field in which rabbit holes are liberally distributed. Among these you can distinguish the ghostly-white form of Glenda the Rabbit." The description of Glenda the Rabbit is "Glenda is white and fluffy. In this light, she appears almost luminescent." She is in the Storage Area.

Instead of touching Glenda the Rabbit:
	say "[one of]You approach Glenda as calmly as you can, but as soon as you get near she darts away to another part of the field[or]Despite tiptoeing towards Glenda, she is wise to your approach and hops away[or]You wander over to Glenda, but before you can bend down to her, she lollops frustratingly out of reach[at random]."

After going east from the Storage Area:
	say "You return down the gravel path that winds between hedges towards the lakeside, and pick your way past that dratted sign.";
	increase the time of day by five minutes;
	continue the action.

Chapter 7 - Reptile House

Section 1 - Outside

The reptile house is backdrop with description "It’s a long, low, semi-circular building that arcs around a large pond. On the curved wall facing you, a large mural has been painted depicting an assortment of lizards and snakes." Understand "building" as the reptile house.

The reptile house is in the Riverside. The reptile house is in the Lakeside.

Section 1 - North End

The Reptile House North is a room with printed name "Reptile House (North)". "You are in long curving room; almost a corridor, in fact. It curves around to the west and to the south. The inner of the two walls is made up of a series of tanks, each of which contains stones, vegetation, heat lamps and so on. Everything to keep a reptile happy. What you don’t see are many actual reptiles − presumably they have hidden themselves away to sleep. The tank in front of which you now stand, though, is an exception." It is covered.

The reptile house in-door is a door. "[if the location is the back side of the reptile house in-door]There is also a bridge to the east over the river, leading to an even larger building decorated with pictures of reptiles. The door to the building, which arcs away to the south, is [end if][if the location is the back side of the reptile house in-door and the reptile house in-door is closed]closed[otherwise if the location is the back side of the reptile house in-door and the reptile house in-door is open]open[otherwise if the reptile house in-door is closed]A door leading out of the reptile house lies closed to the west[otherwise]A door leading out of the reptile house lies open to the west[end if]." It is openable and closed. It is west of the Reptile House North and east of the Riverside.

[The door needs to be listed last]
Rule for choosing notable locale objects for the Reptile House North:
	repeat with item running through things in the Reptile House North:
		if the item is a door:
			set the locale priority of the item to 6;
		otherwise:
			set the locale priority of the item to 5.


The tanks are backdrop with description "The tanks are hard to examine in the dim light, but you imagine the reptiles would find them comfortable." The tanks are in the Reptile House North. Understand "stones" as the tanks. Understand "vegetation" as the tanks. Understand "heat lamps" as the tanks.

A transparent container called the lizard tank is in the Reptile House North. "Lying on a stone within this beautifully rendered lizard tank is a bright red gecko." The description of the lizard tank is "The tank is full of the usual accoutrements for keeping small reptiles happy and comfortable. The front glass panel is hinged to one side with a lock embedded on the other." It is fixed in place, lockable and locked. The green key unlocks the lizard tank.

Mo the Gecko is a female animal. "Mo the Gecko has red colouration, bright eyes and tiny, sharp-looking teeth." She is in the lizard tank. She is undescribed.

Instead of touching Mo the Gecko:
	say "You lean forward to nudge Mo with your nose. Her head whips round, jaws gaping, and before you know it you are being scoured by a torrent of tiny little angle brackets. The stinging is too much and you back away. Perhaps you should leave her be."

After going south from the Reptile House North:
	increase the time of day by three minutes;
	continue the action.

Instead of going nowhere in the Reptile House North when the noun is outside:
	try going west.

Section 2 - South End

The Reptile House South is a room with printed name "Reptile House (South)". "You are in long room, or possibly a wide corridor, that curves around to the north and to the west. Lining the inner of the two walls is a series of large tanks, each of which contains the paraphernalia associated with well cared-for reptiles − branches, logs, rocks and so on. The reptiles themselves, though, are hard to spot; possibly it’s the dim light, possibly they’ve hidden themselves away to sleep[if Odi the Python is in the snake tank]. In one of these tanks, though, the occupant is clearly visible[end if]." It is covered. It is south of the Reptile House North.

The tanks are in the Reptile House South. Understand "paraphernalia" as the tanks. Understand "branches" as the tanks. Understand "logs" as the tanks. Understand "rocks" as the tanks.

A transparent container called the snake tank is in the Reptile House South. "[If Odi the Python is in the snake tank]Coiled and draped over one of the branches in the tank is Odi the Python[otherwise]You stop beside the tank that once held Odi, still recognizable from the immaculate spacing of its contents[end if]." The description of the snake tank is "The tank is full of the usual accoutrements for keeping snakes happy and comfortable.  Unusually, everything in the tank is meticulously spaced out. The front glass panel is hinged to one side with a lock embedded on the other." It is fixed in place, lockable and locked. The green key unlocks the snake tank.

Odi the Python is a female animal. "Odi is a vivid green with white spots spaced out along her back. She is coiled into a spiral and draped nonchalantly over a branch. She regards you coolly, flicking her tongue out occasionally to taste the air." She is in the snake tank. She is undescribed.

The branch is an object in the snake tank. "It's just a branch." It is scenery.

Odi the Gnu is a female gnu with description "She’s a gnu. Agnother gnu, though her hide has taken on a greenish hue."

Instead of touching Odi the Python:
	remove Odi the Python from play;
	now Odi the Gnu is in the Reptile House South;
	increase the time of day by five minutes;
	say "You gently nuzzle the python with your snout. Ouch! You leap back, thinking for a moment that Odi must have bitten you. But no, it was more like an electric shock. Odi now seems to be bathed in blue light. And bloating. You watch, fascinated, as Odi spills out of the tank onto the floor. Fur sprouts from underneath her scales. Two pairs of bumps appear on her underside, growing obscenely into vestigial limbs.[paragraph break]After five minutes or so, the transformation is complete, and Odi the Gnu rises unsteadily to her unaccustomed feet before you."

The reptile house out-door is a door. "[if the location is the back side of the reptile house out-door]A long, low building arcs around the far side of the pond; it is decorated with pictures of reptiles. The nearest door to the building, east of where you stand, is [end if][if the location is the back side of the reptile house out-door and the reptile house out-door is closed]closed[otherwise if the location is the back side of the reptile house out-door and the reptile house out-door is open]open[otherwise if the reptile house out-door is closed]A door leading out of the reptile house lies closed to the west[otherwise]A door leading out of the reptile house lies open to the west[end if]." It is openable and closed. It is west of the Reptile House South and east of the Lakeside.

[The door needs to be listed last]
Rule for choosing notable locale objects for the Reptile House South:
	repeat with item running through things in the Reptile House South:
		if the item is a door:
			set the locale priority of the item to 6;
		otherwise:
			set the locale priority of the item to 5.

After going north from the Reptile House South:
	increase the time of day by three minutes;
	continue the action.

Instead of going nowhere from the Reptile House South when the noun is outside:
	try going west.

Chapter 8 - Aviary

Section 1 - In the Aviary

A bird is a kind of animal. A bird can be within reach or out of reach.

A lump of coal is a kind of thing. The plural of lump of coal is lumps of coal.

The coal sack is an open opaque container.

In the coal sack are 5 lumps of coal.

[I wanted to have an uncountably large amount of coal in this sack, but without the facility for dynamically generating the lumps, my solution wasn't very robust. I resort here to magic instead: if the sack is empty, lost coals find their way back to the sack. This way the player should never be bereft of missiles.]
The description of the coal sack is "The coal sack is made of sackcloth and is covered in coal dust. Exactly what you would expect, really." The coal sack is fixed in place.

Rule for printing the name of the coal sack while not inserting or removing: 
    say "coal sack"; 
    omit contents in listing.

Before searching the coal sack:
	if there is exactly one lump of coal in the coal sack:
		say "You rummage around in the coal sack and locate one more lump of coal." instead;
	otherwise:
		continue the action.

Instead of taking the coal sack:
	say "The sack would be awkward to carry. You reach inside for a lump of coal instead.";
	try taking a random lump of coal.

After taking a lump of coal for the first time:
	say "You manoeuvre your lips around the lump of coal and pick it up. It makes your mouth feel all gritty, and the dust tickles your nose, but you maintain your grip."

[The player will need to throw things at inanimate objects]
The futile to throw things at inanimate objects rule is not listed in the check throwing it at rulebook.

The block throwing at rule is not listed in the check throwing it at rulebook.

A check throwing it at rule:
	if the noun is not carried by the player:
		say "You can’t throw something you’re not carrying."instead.

A check throwing it at rule:
	if the second noun is a person and the second noun is not a bird:
		say "That’s no way to treat your fellow residents." instead.

A check throwing it at rule:
	if the second noun is not a person and the second noun is not the pole and the second noun is not the upper perch and the second noun is not the lower perch and the second noun is not the coal burner:
		say "That seems a little futile." instead.

Before throwing something at someone:
	if the second noun is a bird:
		say "Aggravating [the second noun] would not be wise. Perhaps you should set your sights a little lower. But only a little lower.";
		stop the action;
	otherwise:
		continue the action.

Report throwing it at: say "Thrown."

Instead of touching a bird when the noun is out of reach:
	say "No matter how far you stretch, [the noun] remains frustratingly out of reach."

Instead of touching a bird when the noun is out of reach for the third time:
	say "All this stretching is getting you nowhere. Could you throw something?"

Instead of attacking a bird when the noun is out of reach:
	say "Violence is not the answer to this one. But if it were, you’d need a projectile to perform it at this distance."

Section 2 - North End

The Aviary North is a room with printed name "Aviary (North)". "This room is very dark, so much of the visual detail is lost on you, but a faint fed glow illuminates an open doorway to the south. You are separated from a section of the room by a wooden rail; from the other side comes the strong smell of bird droppings and mouse fur, and the sound of rustling feathers." It is covered.

The wooden rail north is an object in the Aviary North with printed name "wooden rail". "The rail is smooth − varnished, in fact − and very sturdy. The ends jut up flush to the walls to the north and south." It is scenery.

Instead of jumping over the wooden rail north:
	say "There’s not enough room in here for that."

Miron the Condor is a bird. "You can make out a vague silhouette of a bird of prey on a pole." The description of Miron the Condor is "Through very careful olfactory analysis, you recognize the bird as Miron the Condor. He is well known for his raised metabolism − you know, lots of food in, lots of the other stuff out − and the smell in here confirms it." He is on the pole.

Understand "silhouette" as Miron the Condor.

The pole is a supporter in the Aviary North. "As you can’t reach the pole to touch it or smell it, and it’s too dark to get a good look, all you can tell about the pole is that it stands about four foot high." It is scenery.

[We count the number of successful throws rather than attempts.] 
The number of mironic shakes is a number that varies.

After throwing something at the pole:
	increment the number of mironic shakes;
	if a random chance of 1 in 3 succeeds:
		say "[The noun] glance[if the noun is singular-named]s[end if] off the pole and [if the noun is singular-named]is[otherwise]are[end if] lost in the shadows.[run paragraph on]";
		if the noun is a lump of coal and there are no lumps of coal in the coal sack:
			move the noun to the coal sack;
		otherwise if the noun is the keyring:
			say "Oops. You try to recall if you have used all the keys.";
			remove the keyring from play;
			loseKeyring;
		otherwise:
			remove the noun from play;
	otherwise:
		say "[The noun] rebound[if the noun is singular-named]s[end if] off the pole onto the floor in front of you.[run paragraph on]";
		now the noun is in the Aviary North;
		if the noun is the keyring:
			dropKeyring;
	say " [if we have examined Miron the Condor]Miron[otherwise]The bird[end if], disturbed by the vibrations, flutters briefly into the air before settling back down on the pole."

Instead of throwing something at the pole when the number of mironic shakes is 2:
	say "As fun as this is, you don’t seem to be having much luck here. Perhaps you should move on."

The aviary door is a door. "[If the location is the front side of the aviary door]The building to the west is decorated with pictures of birds. Its door[otherwise]The door to the aviary[end if] lies [if open]open[otherwise]closed[end if][if the location is the back side of the aviary door] to the [direction of the aviary door from the location][end if]." The description of the door is "The door is primarily glass, with a selection of birds of prey engraved on it. The blind behind it is drawn." It is openable, closed, lockable and locked. It is west of the Main Concourse and east of the Aviary North. The brown key unlocks the aviary door. Understand "engravings" as the aviary door.

The blind is backdrop with description "If it wasn’t for blinds such as this one, it would be curtains for all of us." The blind is in the Main Concourse and the Aviary North.

Instead of attacking the aviary door:
	say "There must be a less dangerous way of opening the door."

[The door needs to be listed last]
Rule for choosing notable locale objects for the Aviary North:
	repeat with item running through things in the Aviary North:
		if the item is a door:
			set the locale priority of the item to 6;
		otherwise:
			set the locale priority of the item to 5.

After going east from the Aviary North:
	increase the time of day by two minutes;
	continue the action.

Instead of going nowhere in the Aviary North when the noun is outside:
	try going east.

Section 3 - Middle

The Aviary Middle is a room with printed name "Aviary (Middle)". "The only illumination in this room is a dull red glow spilling through the doorway to the south; an inky-blank rectangle in the north wall suggests another exit that way. On the far side of the room are two perches, one higher than the other. You are separated from the perches by a wooden rail that bisects the room." It is covered. It is south of the Aviary North.

The lower perch is a supporter in the Aviary Middle. It is scenery.

The upper perch is a supporter in the Aviary Middle. It is scenery.

The wooden rail south is a supporter in the Aviary Middle with printed name "wooden rail". "The rail is smooth − varnished, in fact − and very sturdy. The ends jut up flush to the walls to the north and south." It is scenery.

Instead of jumping over the wooden rail south:
	say "There’s not enough room in here for that."

[Representing v1.x of the Apache Licence]
Behlendorf the Patchy Eagle is a bird on the lower perch. "The lower perch is occupied by a patchy-looking eagle. The patchy effect comes from the fact that his normally dark plumage contains numerous feathers of bright red and purple, almost like those of a macaw." The description of Behlendorf the Patchy Eagle is "Behlendorf occupies the lower of the two perches and appears older than his companion. He is fast asleep." He is asleep. Understand "lower eagle" as Behlendorf the Patchy Eagle.

Instead of waking Behlendorf the Patchy Eagle:
	say "You don’t want to attract attention with too much noise, and you can’t reach to poke him awake. Any other ideas?"

[Representing v2.x of the Apache Licence]
Striker the Patchy Eagle is a bird on the upper perch. "The upper perch is occupied by another, similarly patchy-looking eagle." The description of Striker the Patchy Eagle is "Striker occupies the upper of the two perches. He cuts a slighter figure than his counterpart, and has a youthful restlessness about him." Understand "upper eagle" as Striker the Patchy Eagle. Understand "higher eagle" as Striker the Patchy Eagle.

Striker the Gnu is a gnu with description "He’s a gnu. Agnother gnu, but the lightness of his stance suggests he flew."

[We count the number of successful throws rather than attempts.] 
The number of behlendic shakes is a number that varies.

After throwing something at the lower perch:
	increment the number of behlendic shakes;
	if a random chance of 1 in 3 succeeds:
		say "[The noun] glance[if the noun is singular-named]s[end if] off the perch and [if the noun is singular-named]is[otherwise]are[end if] lost in the shadows.[run paragraph on]";
		if the noun is a lump of coal and there are no lumps of coal in the coal sack:
			move the noun to the coal sack;
		otherwise if the noun is the keyring:
			say "Oops. You try to recall if you have used all the keys.";
			remove the keyring from play;
			loseKeyring;
		otherwise:
			remove the noun from play;
	otherwise:
		say "[The noun] rebound[if the noun is singular-named]s[end if] off the perch onto the floor in front of you.[run paragraph on]";
		now the noun is in the Aviary North;
		if the noun is the keyring:
			dropKeyring;
	say " [if we have examined Behlendorf the Patchy Eagle]Behlendorf[otherwise]The eagle[end if] seems to be oblivious to the vibrations, however, and remains deeply asleep."

Instead of throwing something at the lower perch when the number of behlendic shakes is 2:
	say "It looks like Behlendorf could sleep through an earthquake. Perhaps you should concentrate your efforts elsewhere."

After throwing something at the upper perch:
	if a random chance of 1 in 3 succeeds:
		say "[The noun] glance[if the noun is singular-named]s[end if] off the perch and [if the noun is singular-named]is[otherwise]are[end if] lost in the shadows.[run paragraph on]";
		if the noun is a lump of coal and there are no lumps of coal in the coal sack:
			move the noun to the coal sack;
		otherwise if the noun is the keyring:
			say "Oops. You try to recall if you have used all the keys.";
			remove the keyring from play;
			loseKeyring;
		otherwise:
			remove the noun from play;
	otherwise:
		say "[The noun] rebound[if the noun is singular-named]s[end if] off the perch onto the floor in front of you.[run paragraph on]";
		now the noun is in the Aviary Middle;
		if the noun is the keyring:
			dropKeyring;
	say " [if we have examined Striker the Patchy Eagle]Striker[otherwise]The eagle[end if], startled by the vibrations, launches into the air. He flaps around the room for a moment before settling on the wooden rail.";
	now the initial appearance of Striker the Patchy Eagle is "Another patchy-looking eagle has settled on the wooden rail.";
	now Striker the Patchy Eagle is on the wooden rail south;
	now Striker the Patchy Eagle is within reach.

Instead of touching Striker the Patchy Eagle when Striker the Patchy Eagle is within reach:
	remove Striker the Patchy Eagle from play;
	now Striker the Gnu is in the Aviary Middle;
	increase the time of day by five minutes;
	say "You brush up against the eagle, who gives a sudden screech. You jump back in surprise, but are even more surprised to see Striker bathed in a blue glow. He starts shivering uncontrollably; feathers cascade to the floor, popped from his skin by a fresh growth of dark fur.[paragraph break]Striker soon loses his grip on the rail and slips off. He struggles pathetically on the floor until realizing his wings have realigned themselves as front legs, and drags himself up. A few moments later, the glow fades leaving Striker the Gnu standing in front of you, rapidly coming to terms with his transformation."

Instead of going nowhere in the Aviary Middle when the noun is outside:
	try going north.

Section 4 - South End

The Aviary South is a room with printed name "Aviary (South)". "This room is divided in two by a brass rail. On the far side of the rail, out of reach, a tall coal burner stands; the fire within fills the room with an infernal red glow." It is covered. It is south of the Aviary Middle.

The brass rail is an object in the Aviary South. "The rail is polished, glinting madly in the firelight, warm to the touch and very sturdy. The ends jut up flush to the walls to the north and south." It is scenery.

Instead of jumping over the brass rail:
	say "There’s not enough room in here for that."

The coal burner is a supporter in the Aviary South. "The coal burner resembles a deep cast-iron grate suspended on a brass pedestal. At floor level, a fiery bird has been engraved in the base." It is scenery.

Instead of touching the coal burner, say "You can get your nose close enough to feel the warmth coming off the burner, but not to actually touch it."

Sparky the Phoenix is a bird. "Standing on the heap of coals is a large and flamboyant red bird that can only be Sparky the Phoenix." The description of Sparky the Phoenix is "Sparky is a large bird with a magnificent red, yellow and orange plumage. She seems to be sleeping peacefully despite the flames lapping at her legs and petite claws." She is on the coal burner. She is asleep.

Instead of waking Sparky the Phoenix:
	say "You don’t want to attract attention with too much noise, and you can’t reach to poke her awake. Any other ideas?"

[We count the number of successful throws rather than attempts.] 
The number of sparcic shakes is a number that varies.

After throwing something at the coal burner:
	increment the number of sparcic shakes;
	if a random chance of 1 in 3 succeeds:
		say "[The noun] glance[if the noun is singular-named]s[end if] off the burner and [if the noun is singular-named]is[otherwise]are[end if] lost in the shadows.[run paragraph on]";
		if the noun is a lump of coal and there are no lumps of coal in the coal sack:
			move the noun to the coal sack;
		otherwise if the noun is the keyring:
			say "Oops. You try to recall if you have used all the keys.";
			remove the keyring from play;
			loseKeyring;
		otherwise:
			remove the noun from play;
	otherwise:
		say "[The noun] rebound[if the noun is singular-named]s[end if] off the burner onto the floor in front of you.[run paragraph on]";
		now the noun is in the Aviary South;
		if the noun is the keyring:
			dropKeyring;
	say " The coals shift slightly. [if we have examined Sparky the Phoenix]Sparky[otherwise]The phoenix[end if] opens her eyes to glare at you contemptuously for a moment before settling back to sleep."

After throwing something at the coal burner when the number of sparcic shakes is 2:
	say "[The noun] hits the burner with a clang. Sparky's head swings towards you, venom in her eyes. She launches herself at you. Before you can react, you are enveloped in roasting flame.";
	end the story saying "Wrong species type (expected help, got flamed)."

The coal sack is in the Aviary South.

The plain brown door is a door. "A plain brown door lies [if open]open[otherwise]closed[end if] to the [direction of the plain brown door from the location]." It is east of the Aviary South. Through it is the Main Concourse.

[The door needs to be listed last]
Rule for choosing notable locale objects for the Aviary South:
	repeat with item running through things in the Aviary South:
		if the item is a door:
			set the locale priority of the item to 6;
		otherwise:
			set the locale priority of the item to 5.

After going east from the Aviary South:
	increase the time of day by two minutes;
	now the plain brown door is closed;
	say "You push through the door, which opens easily and swings back just as easily behind you. Turning, you find the door has slotted itself seamlessly into the wall of the aviary; and with no handle or even keyhole, there is no way of opening it from the outside, and no marker to help you find it again.";
	continue the action.

Instead of going nowhere in the Aviary South when the noun is outside:
	try going east.

Chapter 9 - Way out

The Front Entrance is a room. "You are in a small, brick-paved courtyard. High walls tower over you to the north and south."

The front entrance walls are objects in the Front Entrance. "Tall. Brick. Nothing special, to be honest." They are scenery.

The archway is a door. "[If the location is the back side of the archway]The eastern range of buildings is interrupted by a wide open archway, atop which a clock tower has been set[otherwise]To the west, a wide open archway interrupts a row of buildings atop which a clock tower has been set[end if]." The description of the archway is "The archway is tall and wide; you could probably get two elephants through side-by-side, but a giraffe would have to stoop." It is west of the Front Entrance and east of the Main Concourse. It is open and not openable.

The front gates are a door with indefinite article "the". "To the east are what must be the front gates to the zoo." The description of the front gates is "These are seriously strong-looking gates. They are a mass of chunky steel rails, with reinforced hinges and locks. Could anything short of a stampede break them down?" They are east of the Front Entrance. They are not openable.

The Ticket Booth is a container in the Front Entrance. "To the side of the gates is a ticket booth, shuttered and boarded up for the night." The description of the Ticket Booth is "The booth is a small building. On this side there is tall, narrow window, shuttered and boarded, and a fearsomely secure-looking door." It is opaque, closed, locked and fixed in place.

The tall narrow window is an object. It is part of the Ticket Booth. It is scenery.

The secure-looking door is an object. It is part of the Ticket Booth. It is scenery.

After deciding the scope of the player:
	if the location is the Front Entrance, place the clock tower in scope.

Instead of opening the front gates:
	if the list of followers is empty:
		say "You lower your head. Tense your muscles. Take a deep breath. And then, in a blur of movement, launch yourself as hard as you can at the gates.[paragraph break]Sadly, the gates do not budge, and all you have to show for your efforts is a headache and a dizzy spell. This is clearly not a job for a single gnu. If only you had a herd of them following you around; you are sure that between you, you could batter your way through.";
	otherwise if the number of entries in the list of followers is one:
		say "You line yourself up with the left-hand gate, and while your companion takes the right. You both lower your heads. Tense your muscles. Take a deep breath. And then, in a blur of movement, launch yourselves as hard as you can at the gate.[paragraph break]The gates shift slightly, but are otherwise unharmed: all you have to show for your efforts are a couple of throbbing heads. You will need some more help with this.";
	otherwise if the number of entries in the list of followers is less than five:
		say "You and your herd get into formation, facing the gate. You all lower your heads. Tense your muscles. Take a deep breath. And then, in a blur of movement, launch yourselves as hard as you can at the gates.[paragraph break]The gates wobble gratifyingly, but still hold. They are clearly well made. But you suspect that only a slightly larger herd could break them.";
	otherwise:
		say "You and your herd get into formation, facing the gate. You all lower your heads. Tense your muscles. Take a deep breath. And then, in a blur of movement, launch yourselves as hard as you can at the gates.[paragraph break]With a sudden screech of tearing metal, the gates burst from their hinges and clatter to the ground beneath your hooves. A long, winding driveway lies before you and your herd, leading out into the wide, wide world.";
		if Night-Time is happening:
			increase the score by 1; [bonus point for speed]
		end the story finally saying "You have achieved freedom!"

After going west from the Front Entrance:
	say "You proceed through the archway.";
	increase the time of day by two minutes;
	continue the action.

Instead of going nowhere in the Front Entrance when the noun is outside:
	try going east.